Este capítulo le enseña cómo crear un formulario de usuario de Excel VBA . El formulario de usuario que vamos a crear tiene el siguiente aspecto:

Agregar los controles

Para agregar los controles al formulario de usuario, ejecute los siguientes pasos.

1. Abra el Editor de Visual Basic . Si el Explorador de proyectos no está visible, haga clic en Ver, Explorador de proyectos.

2. Haga clic en Insertar, formulario de usuario. Si la Caja de herramientas no aparece automáticamente, haga clic en Ver, Caja de herramientas. Su pantalla debe configurarse como se muestra a continuación.

3. Agregue los controles enumerados en la tabla siguiente. Una vez que se haya completado, el resultado debe ser coherente con la imagen del formulario de usuario que se mostró anteriormente. Por ejemplo, cree un control de cuadro de texto haciendo clic en TextBox en el cuadro de herramientas. A continuación, puede arrastrar un cuadro de texto en el formulario de usuario. Cuando llegue al marco del automóvil, recuerde dibujar este marco primero antes de colocar los dos botones de opción en él.

4. Cambie los nombres y títulos de los controles de acuerdo con la tabla siguiente. Los nombres se utilizan en el código de Excel VBA. Los subtítulos son los que aparecen en su pantalla. Es una buena práctica cambiar los nombres de los controles. Esto hará que su código sea más fácil de leer. Para cambiar los nombres y títulos de los controles, haga clic en Ver, Ventana Propiedades y haga clic en cada control.

Control	Nombre	Subtítulo
Formulario de usuario	DinnerPlannerUserForm	Planificador de cenas
Caja de texto	NameTextBox
Caja de texto	PhoneTextBox
Cuadro de lista	CityListBox
Caja combo	DinnerComboBox
Casilla de verificación	DateCheckBox1	13 de junio
Casilla de verificación	DateCheckBox2	20 de junio
Casilla de verificación	DateCheckBox3	27 de junio
Marco	CarFrame	Carro
Botón de opción	CarOptionButton1	sí
Botón de opción	CarOptionButton2	No
Caja de texto	MoneyTextBox
Botón Girar	MoneySpinButton
Botón de comando	OKButton	OK
Botón de comando	ClearButton	Claro
Botón de comando	CancelarBotón	Cancelar
7 etiquetas	No hay necesidad de cambiar	Nombre :, Número de teléfono :, etc.

Nota: un cuadro combinado es una lista desplegable desde donde un usuario puede seleccionar un elemento o completar su propia elección. Solo se puede seleccionar uno de los botones de opción.

Mostrar el formulario de usuario

Para mostrar el formulario de usuario, coloque un botón de comando en su hoja de trabajo y agregue la siguiente línea de código:

Private Sub CommandButton1_Click()

DinnerPlannerUserForm.Show

End Sub

Ahora vamos a crear el Sub UserForm_Initialize. Cuando utilice el método Show para el formulario de usuario, este sub se ejecutará automáticamente.

1. Abra el Editor de Visual Basic .

2. En el Explorador de proyectos, haga clic con el botón derecho en DinnerPlannerUserForm y luego haga clic en Ver código.

3. Elija Userform de la lista desplegable de la izquierda. Elija Inicializar en la lista desplegable de la derecha.

4. Agregue las siguientes líneas de código:

Private Sub UserForm_Initialize()

'Empty NameTextBox
NameTextBox.Value = ""

'Empty PhoneTextBox
PhoneTextBox.Value = ""

'Empty CityListBox
CityListBox.Clear

'Fill CityListBox
With CityListBox
    .AddItem "San Francisco"
    .AddItem "Oakland"
    .AddItem "Richmond"
End With

'Empty DinnerComboBox
DinnerComboBox.Clear

'Fill DinnerComboBox
With DinnerComboBox
    .AddItem "Italian"
    .AddItem "Chinese"
    .AddItem "Frites and Meat"
End With

'Uncheck DataCheckBoxes
DateCheckBox1.Value = False
DateCheckBox2.Value = False
DateCheckBox3.Value = False

'Set no car as default
CarOptionButton2.Value = True

'Empty MoneyTextBox
MoneyTextBox.Value = ""

'Set Focus on NameTextBox
NameTextBox.SetFocus

End Sub

Explicación: los cuadros de texto se vacían, los cuadros de lista y los cuadros combinados están llenos, las casillas de verificación están desmarcadas, etc.

Asignar las macros

Ahora hemos creado la primera parte del formulario de usuario. Aunque ya se ve bien, no pasará nada cuando hagamos clic en los botones de comando en el formulario de usuario.

1. Abra el Editor de Visual Basic .

2. En el Explorador de proyectos, haga doble clic en DinnerPlannerUserForm.

3. Haga doble clic en el botón Girar dinero.

4. Agregue la siguiente línea de código:

Private Sub MoneySpinButton_Change()

MoneyTextBox.Text = MoneySpinButton.Value

End Sub

Explicación: esta línea de código actualiza el cuadro de texto cuando usa el botón de giro.

5. Haga doble clic en el botón Aceptar.

6. Agregue las siguientes líneas de código:

Private Sub OKButton_Click()

Dim emptyRow As Long

'Make Sheet1 active
Sheet1.Activate

'Determine emptyRow
emptyRow = WorksheetFunction.CountA(Range("A:A")) + 1

'Transfer information
Cells(emptyRow, 1).Value = NameTextBox.Value
Cells(emptyRow, 2).Value = PhoneTextBox.Value
Cells(emptyRow, 3).Value = CityListBox.Value
Cells(emptyRow, 4).Value = DinnerComboBox.Value

If DateCheckBox1.Value = True Then Cells(emptyRow, 5).Value = DateCheckBox1.Caption

If DateCheckBox2.Value = True Then Cells(emptyRow, 5).Value = Cells(emptyRow, 5).Value & " " & DateCheckBox2.Caption

If DateCheckBox3.Value = True Then Cells(emptyRow, 5).Value = Cells(emptyRow, 5).Value & " " & DateCheckBox3.Caption

If CarOptionButton1.Value = True Then
    Cells(emptyRow, 6).Value = "Yes"
Else
    Cells(emptyRow, 6).Value = "No"
End If

Cells(emptyRow, 7).Value = MoneyTextBox.Value

End Sub

Explicación: primero, activamos Sheet1. A continuación, determinamos emptyRow. La variable emptyRow es la primera fila vacía y aumenta cada vez que se agrega un registro. Finalmente, transferimos la información del formulario de usuario a las columnas específicas de emptyRow.

7. Haga doble clic en el botón Borrar.

8. Agregue la siguiente línea de código:

Private Sub ClearButton_Click()

Call UserForm_Initialize

End Sub

Explicación: esta línea de código llama a Sub UserForm_Initialize cuando hace clic en el botón Borrar.

9. Haga doble clic en el botón Cancelar.

10. Agregue la siguiente línea de código:

Private Sub CancelButton_Click()

Unload Me

End Sub

Explicación: esta línea de código cierra el formulario de usuario cuando hace clic en el botón Cancelar.

Probar el formulario de usuario

Salga del Editor de Visual Basic, ingrese las etiquetas que se muestran a continuación en la fila 1 y pruebe el formulario de usuario.

Resultado:

1/11 Completado! Obtenga más información sobre los formularios de usuario>
Siguiente capítulo: Rango